Funktionen › SUMMEWENNS
SUMMEWENNS in Excel: Summe mit mehreren Bedingungen, einfach erklärt
SUMMEWENNS addiert nur die Zeilen, die alle Bedingungen gleichzeitig erfüllen. Typische Fragen: „Wie viel Umsatz hat Berlin mit Kaffee gemacht?“ oder „Wie hoch ist die Summe aller Umsätze zwischen 900 und 2000 €?“.
Achtung bei der Reihenfolge: Anders als bei SUMMEWENN steht der Bereich mit den Zahlen ganz vorn. Danach folgen Paare aus Bereich und Kriterium, so viele du brauchst.
Die Funktion klappt auch mit nur einer Bedingung. Viele nutzen deshalb immer SUMMEWENNS.
Syntax
=SUMMEWENNS(Summe_Bereich; Kriterienbereich1; Suchkriterien1; …) Auf Englisch: SUMIFS
Summe_BereichDer Bereich mit den Zahlen, die addiert werden. Er steht hier an erster Stelle.
Kriterienbereich1Der erste Bereich, in dem ein Kriterium geprüft wird. Beispiel: die Spalte mit den Filialen.
Suchkriterien1Das Kriterium für diesen Bereich, etwa
"Berlin"oder">=900". Weitere Paare aus Bereich und Kriterium hängst du einfach an.
Beispiele
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Monat | Filiale | Produkt | Umsatz |
| 2 | Januar | Berlin | Kaffee | 1800 |
| 3 | Januar | München | Tee | 950 |
| 4 | Februar | Berlin | Tee | 720 |
| 5 | Februar | Berlin | Kaffee | 2100 |
| 6 | Februar | München | Kaffee | 1650 |
| 7 | ||||
| 8 | Berlin, Kaffee | 3900 |
B8: =SUMMEWENNS(D2:D6;B2:B6;"Berlin";C2:C6;"Kaffee") Ergebnis: 3900Beide Bedingungen müssen in derselben Zeile stimmen. Das trifft auf zwei Zeilen zu: 1800 + 2100.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Monat | Filiale | Produkt | Umsatz |
| 2 | Januar | Berlin | Kaffee | 1800 |
| 3 | Januar | München | Tee | 950 |
| 4 | Februar | Berlin | Tee | 720 |
| 5 | Februar | Berlin | Kaffee | 2100 |
| 6 | Februar | München | Kaffee | 1650 |
| 7 | ||||
| 8 | 900 bis unter 2000 | 4400 |
B8: =SUMMEWENNS(D2:D6;D2:D6;">=900";D2:D6;"<2000") Ergebnis: 4400Zwei Bedingungen auf dieselbe Spalte ergeben einen Wertebereich: alle Umsätze ab 900 und unter 2000.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Monat | Filiale | Produkt | Umsatz |
| 2 | Januar | Berlin | Kaffee | 1800 |
| 3 | Januar | München | Tee | 950 |
| 4 | Februar | Berlin | Tee | 720 |
| 5 | Februar | Berlin | Kaffee | 2100 |
| 6 | Februar | München | Kaffee | 1650 |
| 7 | ||||
| 8 | Filiale | München | ||
| 9 | Monat | Februar | ||
| 10 | Umsatz | 1650 |
B10: =SUMMEWENNS(D2:D6;B2:B6;B8;A2:A6;B9) Ergebnis: 1650Die Kriterien stehen in B8 und B9. Tippst du dort eine andere Filiale oder einen anderen Monat ein, rechnet die Formel neu.
Jetzt üben
Lädt…
Zur ganzen Lektion: SUMMEWENNS: mehrere Bedingungen →
Häufige Fehler
- Die gewohnte Reihenfolge übernehmen. Anders als bei
SUMMEWENNsteht beiSUMMEWENNSder Summenbereich vorn, nicht hinten. Sonst sucht Excel in den Zahlen nach deinem Text. - Unterschiedlich große Bereiche. Alle Bereiche müssen gleich viele Zeilen haben. In Excel erscheint sonst
#WERT!. - Ein „oder“ erwarten. Alle Bedingungen müssen gleichzeitig gelten. Für „Berlin oder München“ addierst du zwei
SUMMEWENNS. - Vergleich ohne Anführungszeichen.
>=900allein geht nicht. Schreib">=900"oder mit Zellbezug">="&B8.
Lektionen zum Üben von SUMMEWENNS
- SUMMEWENNS: mehrere Bedingungen: Addiere mit SUMMEWENNS nach zwei oder mehr Bedingungen gleichzeitig, zum Beispiel die Gehälter der Referenten einer Abteilung.
- Übung: SUMMEWENNS: Übungen mit der Funktion SUMMEWENNS: zwei und drei Bedingungen, Text mit Zahl und ungleich.
- Summenformeln reparieren: Finde und korrigiere typische Fehler in SUMMEWENN und SUMMEWENNS: fehlende Anführungszeichen, vertauschte Argumente, ungleich große Bereiche.
- Zusammenfassung: Summenfunktionen: Wiederholung von SUMME, SUMMEWENN und SUMMEWENNS: In jeder Übung wählst du die passende Funktion für die Frage.
- Monatsabschluss im Verkauf: Ein Fall aus der Praxis: Erstelle den Monatsabschluss eines Elektronikgeschäfts mit SUMMEWENN, ZÄHLENWENN, MITTELWERTWENN, MAX, XVERWEIS und WENN.